אופיס 365 סיכום שעות באקסס

[FullTime]

עשיתי באקסס רישום שעות עבודה.

בדו"ח כשאני רוצה לעשות סיכום חודשי של השעות,
כשהוא עובר את ה24 שעות הוא עובר ליום חדש והוא מציג רק את השעות שעוברות את ה24,
איך אני אמור לעשות את הסיכום?

תודה

 

[שמח לעזור]

זה עניין של פורמט, הוא באמת מחשבן גם את הימים.
אתה צריך לשרשר ביטוי, שבו חשבון הפרש התאריכים בין הסיכום לבין 30/12/1899 (תאריך הפתיחה של אקסס), ואת זה תעצב בימים, ואח"כ סיכום רגיל ייתן לך את השעות.

 

[FullTime]

זה עניין של פורמט, הוא באמת מחשבן גם את הימים.
אתה צריך לשרשר ביטוי, שבו חשבון הפרש התאריכים בין הסיכום לבין 30/12/1899 (תאריך הפתיחה של אקסס), ואת זה תעצב בימים, ואח"כ סיכום רגיל ייתן לך את השעות.

1. בין סיכום השעות?
(איך אני מחשב טווח בין שני תאריכים באקסס? אין לי עצבים לחפש את זה עכשיו)

2. איזה עיצוב ימים, תאריך רגיל?

 

[FullTime]

אף אחד לא יודע?

 

[moishy]

כרגיל יש יותר מדרך אחת הנה דוגמא אחת, בערב אם יהיה לי זמן אראה לך שיטה יותר ידידותית למשתמש.

Sub test()

    Dim dtStartDate As Date
    Dim dtEndDate As Date

    dtStartDate = #4/18/2013 11:10:59 PM#
    dtEndDate = #4/19/2013 12:29:49 AM#

    Debug.Print Format(DateDiff("h", dtStartDate, dtEndDate), "00") _
                & ":" & _
                Format(DateDiff("n", dtStartDate, dtEndDate) Mod 60, "00") _
                & ":" & _
                Format(DateDiff("s", dtStartDate, dtEndDate) Mod 60, "00")
End Sub

 

[תמנתי ווב דיזיין]

אני מחשבת שעת סיום פחות שעת התחלה
וסך לכל פעולה, וסך יומי
בסוף החודש אני מחשבת את כל הדקות בנפרד
אחר כך את כל השעות בנפרד.
מחלקת את הדקות ב- 60 לקבל כמה שעות היו בדקות
ואחר כך הופכת לעשרוני כדי לחייב.

אני מעלה סתם דוגמא לאיך זה נראה.
אני לא יודעת תכנות ולכן עושה זאת בצורה פשוטה כזו

 

[moishy]

ועכשיו לאפשרות השניה, לא להבהל מכמות הקוד, יש להעתיק את הקוד הבא למודול חדש:

Option Explicit

Declare Function GetProfileString Lib "kernel32.dll" Alias "GetProfileStringA" _
                                  (ByVal lpAppName As String, ByVal lpKeyName As String, ByVal lpDefault As String, _
                                   ByVal lpReturnedString As String, ByVal nSize As Long) As Long

Public Function GetTimeDelimiter() As String
    Const conMaxSize = 10
    Dim strBuffer As String
    Dim intLen As Integer
    strBuffer = Space(conMaxSize)
    intLen = GetProfileString("intl", "sTime", "", strBuffer, conMaxSize)
    GetTimeDelimiter = Left(strBuffer, intLen)
End Function

Function fCustomDateDiff(dtStartDate As Date, dtEndDate As Date, _
                         Optional strFormat As String = "H:MM:SS") As String
' Return the difference between two times,
' formatted as specified in strFormat.
    Dim lngSeconds As Long
    Dim sngMinutes As Single
    Dim sngHours As Single
    Dim sngDays As Single
    Dim intSeconds As Integer
    Dim intMinutes As Integer
    Dim intHours As Integer
    Dim intRoundedHours As Integer
    Dim intRoundedMinutes As Integer
    Dim strDay As String
    Dim strHour As String
    Dim strMinute As String
    Dim strSecond As String
    Dim strOut As String
    Dim lngFullDays As Long
    Dim lngFullHours As Long
    Dim lngFullMinutes As Long
    Dim strDelim As String
    ' If you don't want to use the local delimiter,
    ' but a specific one, replace the next line with
    ' this:
    ' strDelim = ":"
    strDelim = GetTimeDelimiter()
    ' Calculate the full number of seconds in the interval.
    ' This limits the calculation to 2 billion seconds
    ' (68 years or so), but that's not too bad. Then calculate
    ' the difference in minutes, hours, and days, as well.
    lngSeconds = DateDiff("s", dtStartDate, dtEndDate)
    sngMinutes = lngSeconds / 60
    sngHours = sngMinutes / 60
    sngDays = sngHours / 24
    ' Get the full hours and minutes, for later display.
    lngFullDays = Int(sngDays)
    lngFullHours = Int(sngHours)
    lngFullMinutes = Int(sngMinutes)

    ' Get the incremental amount of each unit.
    intHours = Int((sngDays - lngFullDays) * 24)
    intMinutes = Int((sngHours - lngFullHours) * 60)
    intSeconds = CInt((sngMinutes - lngFullMinutes) * 60)
    ' In some instances, time values must be rounded.
    ' The next two lines depend on the fact that a true statement
    ' has a value of -1 and a false statement has a value of 0.
    ' The code needs to add 1 to the value if the following
    ' expression is true, and 0 if not.
    intRoundedHours = intHours - (intMinutes > 30)
    intRoundedMinutes = intMinutes - (intSeconds > 30)
    strDay = "ימים"
    strHour = "שעות"
    strMinute = "דקות"
    strSecond = "שניות"
    If lngFullDays = 1 Then strDay = "יום"
    Select Case strFormat
        Case "D H"
            If intRoundedHours = 1 Then strHour = "שעה"
            strOut = lngFullDays & " " & strDay & " " & _
                     intRoundedHours & " " & strHour
        Case "D H M"
            If intHours = 1 Then strHour = "שעה"
            If intRoundedMinutes = 1 Then strMinute = "דקה"
            strOut = lngFullDays & " " & strDay & " " & _
                     intHours & " " & strHour & " " & _
                     intRoundedMinutes & " " & strMinute
        Case "D H M S"
            If intHours = 1 Then strHour = "שעה"
            If intMinutes = 1 Then strMinute = "דקה"
            If intSeconds = 1 Then strSecond = "שניה"
            strOut = lngFullDays & " " & strDay & " " & _
                     intHours & " " & strHour & " " & _
                     intMinutes & " " & strMinute & " " & _
                     intSeconds & " " & strSecond
        Case "D H:MM"      ' 3 ימים 2:46"
            strOut = lngFullDays & " " & strDay & " " & _
                     intHours & strDelim & Format(intRoundedMinutes, "00")
        Case "D HH:MM"     ' 3 ימים 02:46"
            strOut = lngFullDays & " " & strDay & " " & _
                     Format(intHours, "00") & strDelim & _
                     Format(intRoundedMinutes, "00")
        Case "D HH:MM:SS"  ' 3 ימים 02:45:45"
            strOut = lngFullDays & " " & strDay & " " & _
                     Format(intHours, "00") & strDelim & _
                     Format(intMinutes, "00") & strDelim & _
                     Format(intSeconds, "00")
        Case "H M"         ' 74 שעות 46 דקות"
            If lngFullHours = 1 Then strHour = "שעה"
            If intRoundedMinutes = 1 Then strMinute = "דקה"
            strOut = lngFullHours & " " & strHour & " " & _
                     intRoundedMinutes & " " & strMinute
        Case "H:MM"        ' 74:46
            strOut = lngFullHours & strDelim & _
                     Format(intRoundedMinutes, "00")
        Case "H:MM:SS"     ' 74:45:45
            strOut = lngFullHours & strDelim & _
                     Format(intMinutes, "00") & strDelim & _
                     Format(intSeconds, "00")
        Case "M S"         ' 4485 דקות 45 שניות
            If lngFullMinutes = 1 Then strMinute = "דקה"
            If intSeconds = 1 Then strSecond = "שניה"
            strOut = lngFullMinutes & " " & strMinute & " " & _
                     intSeconds & " " & strSecond
        Case "M:SS"        ' 4485:45
            strOut = lngFullMinutes & strDelim & _
                     Format(intSeconds, "00")
        Case Else
            strOut = ""
    End Select
    fCustomDateDiff = strOut
End Function

לבדוק את הפונקציה יש להעתיק את הקוד הבא ולהפעילו:

Sub TestInterval()
    Dim dtStartDate As Date
    Dim dtEndDate As Date
    dtStartDate = #4/18/2013 11:10:59 PM#
    dtEndDate = #4/19/2013 12:29:49 AM#
    Debug.Print fCustomDateDiff(dtStartDate, dtEndDate, "D H")
    Debug.Print fCustomDateDiff(dtStartDate, dtEndDate, "D H M")
    Debug.Print fCustomDateDiff(dtStartDate, dtEndDate, "D H M S")
    Debug.Print fCustomDateDiff(dtStartDate, dtEndDate, "D H:MM")
    Debug.Print fCustomDateDiff(dtStartDate, dtEndDate, "D HH:MM")
    Debug.Print fCustomDateDiff(dtStartDate, dtEndDate, "D HH:MM:SS")
    Debug.Print fCustomDateDiff(dtStartDate, dtEndDate, "H M")
    Debug.Print fCustomDateDiff(dtStartDate, dtEndDate, "H:MM")
    Debug.Print fCustomDateDiff(dtStartDate, dtEndDate, "H:MM:SS")
    Debug.Print fCustomDateDiff(dtStartDate, dtEndDate, "M S")
    Debug.Print fCustomDateDiff(dtStartDate, dtEndDate, "M:SS")
End Sub

מה שיש לשים לב בשתי השיטות הערך המוחזר הוא מחרוזת טקסט ולא מספר כך שאם יש צורך בחישובים (משכורת, לדוגמא) נתקל בבעיה. לצורך כך כתבתי את הפונקציה הבאה:

Public Function fCalculateWages(strFormattedTime As String, _
                                curHourlyWage As Currency, _
                                Optional blnIncludeSeconds As Boolean = True) As Currency


    Dim arr As Variant
    Dim intHours, intMinutes, intSeconds As Integer
    Dim intTemp As Integer

    arr = Split(strFormattedTime, ":")

    intHours = CCur(arr(0)) * 3600
    intMinutes = CCur(arr(1)) * 60
    intSeconds = CCur(arr(2))

    intTemp = IIf(blnIncludeSeconds = True, intHours + intMinutes + intSeconds, intHours + intMinutes)

    fCalculateWages = intTemp * curHourlyWage / 3600

End Function

לפונקציה הזאת יש שלש פרמטרים:
1. strFormattedTime - מחרוזת המכילה את הזמן (הוא התוצאה של שתי השיטות האמורות).
2. curHourlyWage - מספר (בפורמט מטבע) שהוא סך השכר לשעה.
3. blnIncludeSeconds - ערך אמת/שקר המציין האם לחשב גם את השניות, ברירת המחדל הוא כן.

סליחה על האריכות, ואידך זיל גמור.
​

 

[FullTime]

מוישי.
אני ע"א גדול מאוד במודולים ובVB
אני עובד בינתיים.. רק עם מאקרואים וכו'.
אם יש לך כוח אולי תסביר לי איך אני עושה את המודול הזה.

נכון לעכשיו הצלחתי להגיע לסיכום השעות בצורת מספר דהיינו, שהוא מציג לי: 85.75.
אני רק לא מצליח להמיר את זה לפורמט שעה: שיירשם לי 85:45.

בכל אופן רוב תודות.

 

[FullTime]

...
אני מעלה סתם דוגמא לאיך זה נראה.
אני לא יודעת תכנות ולכן עושה זאת בצורה פשוטה כזו

אם מודבר באקסל, זה סתם סיבוך כי באקסל מאוד קל לחשב שעות.
וגם להכפיל אותו בסכום
אם מדובר באקסס, לא הצלחתי לעלות על זה.
מה שהצלחתי זה לחלק את סכום השעות במספרי. וכנ"ל בהודעה הקודמת.

 

[יעילות]

מצ''ב קובץ באקסל קרדיט למיכאל אבידן מנהל פורום אופיס בתפוז וhttp://www.tapuz.co.il/Forums2008/ForumPage.aspx?ForumId=62&r=1לפורום http://www.mabat3.co.il/phpBB3/index.phpשתיווך ביננו.

 

[FullTime]

מצ''ב קובץ באקסל קרדיט למיכאל אבידן מנהל פורום אופיס בתפוז וhttp://www.tapuz.co.il/Forums2008/ForumPage.aspx?ForumId=62&r=1לפורום http://www.mabat3.co.il/phpBB3/index.phpשתיווך ביננו.

עשיתי כבר תוכנה באקסל שאני משתמש עם זה היום
אבל יש לי בעיה עם ההזנה שהיא מתבצעת בצורה מאוד ידנית כראוי לאקסל
ועם הדוחות שכל פעם אני צריך לעצב את זה. אני לא יכול להשתמש עם דוח כזה כי כל יום יש לי כמה פעמים שאני עובד, וכמו"כ אני עובד אצל כמה אנשים.

 

[moishy]

תעלה לכאן דוגמא, ובל"נ אעשה את השינויים הנדרשים.

 

[FullTime]

תעלה לכאן דוגמא, ובל"נ אעשה את השינויים הנדרשים.

הודעה בפרטי..

 

[HUBHCBH]

יש לי קובץ שבו אני מסכם שעות, כיוון שהוא לא נועד לשעות שבו מתחלף התאריך לכן לא נצרכתי לקוד שמסדר את השעות ואת הימים יחדיו למשל כשרושמים שעה 23:00 ואח"כ 1:00, יהיה בעיה בסיכום שעות, לא נגעתי בזה כי לא נצרכתי,
אבל... בסוף תקופה לשמל של 30 יום שכל יום נרשמה שעה אחת, בסיכום ניהיה בעיה, כי זה יותר מ 24 שעות.... ( הסיכום הכספי יוצא מצוין), האם יש דרך שלא יוגבל שדה הסיכום של השעות ל 24 שעות?
שגם יוכל לרשום בסיכום 30:25 ?

הדוגמא הכי פשוט אני חושב שתיהיה להציג בתוך שדה טקסט פשוט שיציג כאילו את השעות לפי חישוב הנצרך, ומהו החישוב???
תודה רבה

 

[FullTime]

בעבר הועלה כאן קוד בשביל זה ע"י מוישי שאני לא מוצא את זה עכשיו, אבל היה שם קישור לאתר של מיקרוסופט, ויש לי את הקובץ אצלי. רצו"ב.
יש בו קוד שמסכם את השעות בפורמט שעה...
אבל יש בעיה שהוא מקבל את זה כטקסט, כך, שלא ניתן לעשות עליו חושבים..
אבל אפשר להציג את השעות עם זה, והחישוב יתבצע על תא מספרי...

 

[HUBHCBH]

תודה רבה
אכן כן מצאתי גם במיקרוספט את הקובץ תוך כדי...
הנה הקישור להסבר מלא
http://office.microsoft.com/he-il/access-help/HA001110218.aspx