אופיס 365 איך מבצעים שינוי פונט X בפונט Y, או גודלו, על ידי מאקרו?

[נירוש]

אני מעוניינת להחליף במסמך וורד בכל מקום שמופיע פונט אריאל בפונט דוד, וכן לשנות את גדול הפונט.
ניסיתי לבצע הקלטה במאקרו, אך זה לא יצר את המאקרו המתאים. אלה התוצאות:
This user does not have permission to use the HTML BB code.

 

[Yisrael]

בבקשה (שיניתי מאריאל לדויד ומ-11 ל-20 לצורך הדוגמה)

    With Selection.Find
        .ClearFormatting
        .Format = True
        .text = ""
        .Font.Name = "Arial"
        .Font.Size = 11
        .Replacement.text = ""
        .Replacement.Font.Name = "david"
        .Replacement.Font.Size = 20
        .Wrap = wdFindContinue
        .Execute Replace:=wdReplaceAll
    End With

 

[צורת הדף]

בבקשה (שיניתי מאריאל לדויד ומ-11 ל-20 לצורך הדוגמה)

    With Selection.Find
        .ClearFormatting
        .Format = True
        .text = ""
        .Font.[COLOR=Red]NameBi [/COLOR]= "Arial"
        .Font.[COLOR=Red]SizeBi [/COLOR]= 11
        .Replacement.text = ""
        .Replacement.Font.[COLOR=Red]NameBi [/COLOR]= "david"
        .Replacement.Font.[COLOR=Red]SizeBi [/COLOR]= 20
        .Wrap = wdFindContinue
        .Execute Replace:=wdReplaceAll
    End With

...

 

[נירוש]

תודה רבה!
זה עובד מצוין.

 

[Yisrael]

...

אכן רבינו הגדול צודק (כמו תמיד) כשמדובר בעברית או כל שפה הנכתבת מימין לשמאל...

 

[נירוש]

בקשה נוספת אם אפשר -

מה צריך להוסיף לפקודה כדי שהיא תעשה זאת לכל המסמכים בתיקיה?

תודה!

 

[Yisrael]

בקשה נוספת אם אפשר -

מה צריך להוסיף לפקודה כדי שהיא תעשה זאת לכל המסמכים בתיקיה?

תודה!

יש להפעיל את ה sub שנקרא UpdateDocuments, יעבור על כל הקבצים שבתיקייה שתבחרי עם סיומת docx (קבצי וורד רגילים).

בהצלחה!

Sub UpdateDocuments()
Application.ScreenUpdating = False
Dim strFolder As String, strFile As String, wdDoc As Document
strFolder = GetFolder
If strFolder = "" Then Exit Sub
strFile = Dir(strFolder & "\*.docx", vbNormal)
While strFile <> ""
  Set wdDoc = Documents.Open(FileName:=strFolder & "\" & strFile, AddToRecentFiles:=False, Visible:=False)
  With wdDoc

     With Selection.Find
        .ClearFormatting
        .Format = True
        .text = ""
        .Font.NameBi = "Arial"
        .Font.SizeBi = 11
        .Replacement.text = ""
        .Replacement.Font.NameBi = "david"
        .Replacement.Font.SizeBi = 20
        .Wrap = wdFindContinue
        .Execute Replace:=wdReplaceAll
    End With
    
    .Close SaveChanges:=True
  End With
  strFile = Dir()
Wend
Set wdDoc = Nothing
Application.ScreenUpdating = True
End Sub
 
Function GetFolder() As String
Dim oFolder As Object
GetFolder = ""
Set oFolder = CreateObject("Shell.Application").BrowseForFolder(0, "בחירת תיקייה", 0)
If (Not oFolder Is Nothing) Then GetFolder = oFolder.Items.Item.Path
Set oFolder = Nothing
End Function

 

[נירוש]

תודה לישראל!

תוכל רק להנחות אותי איך אני מכניסה למאקרו את התיקיה - לדוגמה תיקיה שנקראת 1 כונן D, זה לא עובד לי, ומבקש את התיקיה.

תודה!

 

[Yisrael]

לא הבנתי, הפעלת את המאקרו? הוא אמור לבקש ממך לבחור תיקייה, תבחרי את התיקייה שבה נמצאים הקבצים שאת רוצה שהוא יעבוד עליהם. מה הוא עושה? תעלי לפה תמונה

 

[נירוש]

לישראל שלום
הדבקתי את המאקרו כפי שקיבלתי אותו ממך ללא שינוי. רצ"ב תמונה.
פתחתי מסמך מתיקיה מסוימת וביצעתי "הפעל מאקרו" - ונתבקשתי לבחור תיקיה.
בחרתי תיקיה, והמאקרו עבד רק על הקובץ הנוכחי, ולא שינה את שאר הקבצים בתיקיה.
תודה!

 

[Yisrael]

א. כשאת אומרת שהוא עבד על הקובץ הנוכחי את מתכוונת על הקובץ שמתוכו הפעלת את המאקרו? האם הקובץ הזה לא נמצא בתיקייה שבחרת?

ב. האם הקבצים שנמצאים בתיקייה שבחרת הם בסיומת docx או doc?

 

[Yisrael]

כפלות

 

[נירוש]

א. כשאת אומרת שהוא עבד על הקובץ הנוכחי את מתכוונת על הקובץ שמתוכו הפעלת את המאקרו? האם הקובץ הזה לא נמצא בתיקייה שבחרת?

ב. האם הקבצים שנמצאים בתיקייה שבחרת הם בסיומת docx או doc?

אכן. על קובץ אחד מתוך שלשה הפעלתי מאקרו, והוא ביצע את המאקרו על אותו האחד, ולא על השאר שבאותה התיקיה.

הקבצים הם docx

אגב - אם ישנה הוראה "בצע את הפעולה גם בשאר הקבצים" מדוע צריך להראות לו באיזה תיקיה זה נמצא? הוא לא אמור לדעת לבד - שזה באותה התיקיה של הקובץ הנוכחי?

 

[Yisrael]

אין הוראה להפעיל את המאקרו על שאר הקבצים, יש הוראה להפעיל את המאקרו על התיקייה שבחרת, תפעילי את המאקרו מקובץ אחר שלא נמצא באותה תיקייה.

 

[נירוש]

אין הוראה להפעיל את המאקרו על שאר הקבצים, יש הוראה להפעיל את המאקרו על התיקייה שבחרת, תפעילי את המאקרו מקובץ אחר שלא נמצא באותה תיקייה.

תודה. אך זה עדיין לא מבצע את הפעולה על התיקיה. רק על הקובץ הפתוח.
ניסית את זה אצלך ואצלך זה עובד?

 

[Yisrael]

זה מאוד מוזר.. את בטוחה שבקבצים שנמצאים בתיקייה שבחרת יש טקסט בגופן עברי אריאל בגודל 11?

אצלי זה עובד מצויין...

 

[נירוש]

יישר כח גדול לישראל שבעקשנות ובסבלנות רבה עזר לי באופן פרטי עד למציאת פתרון.

 

[Yisrael]

מכיון שאני כבר לא יכול לערוך את ההודעה המקורית שלי אני אכתוב כאן את הקוד המתוקן ואולי יהיה למישהו תועלת מזה גם בעתיד.

Sub UpdateDocuments1()
Application.ScreenUpdating = False
Dim strFolder As String, strFile As String, wdDoc As Document
strFolder = GetFolder
If strFolder = "" Then Exit Sub
strFile = Dir(strFolder & "\*.docx", vbNormal)
While strFile <> ""
  Set wdDoc = Documents.Open(FileName:=strFolder & "\" & strFile, AddToRecentFiles:=False, Visible:=False)
  With wdDoc
     With .Content.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Format = True
        .text = ""
        .Font.NameBi = "Arial"
        .Font.SizeBi = 11
        .Replacement.text = ""
        .Replacement.Font.NameBi = "David"
        .Replacement.Font.SizeBi = 20
        .Wrap = wdFindContinue
        .Execute Replace:=wdReplaceAll
    End With
    .Close SaveChanges:=True
  End With
  strFile = Dir()
Wend
Set wdDoc = Nothing
Application.ScreenUpdating = True
End Sub

Function GetFolder() As String
Dim oFolder As Object
GetFolder = ""
Set oFolder = CreateObject("Shell.Application").BrowseForFolder(0, "בחירת תיקייה", 0)
If (Not oFolder Is Nothing) Then GetFolder = oFolder.Items.Item.Path
Set oFolder = Nothing
End Function