אופיס 365 אתחול יציאת USB

[נדמ]

שלום.

מישהו מכיר דרך לבצע אתחול על יציאת USB (כדי שהמחשב יזהה שוב את ההתקן המחובר אליו) בלי להוציא פיזית את החיבור ולהכניס שוב?
אם גם יש דרך לעשות דרך קוד של אקסס זה יהיה עוד יותר טוב.

תודה.

 

[SHLOMOSI]

מצטרף לשאלה

 

[Rרחמים]

שלום.

מישהו מכיר דרך לבצע אתחול על יציאת USB (כדי שהמחשב יזהה שוב את ההתקן המחובר אליו) בלי להוציא פיזית את החיבור ולהכניס שוב?
אם גם יש דרך לעשות דרך קוד של אקסס זה יהיה עוד יותר טוב.

תודה.

גם אני הייתי שמח לדעת איך מטפלים בהתקנת התקנים דרך קוד, אבל אפשר לשאול אותך למה האתחול הזה יכול להועיל?

 

[moishy]

אפשר, צריך למחוק את המפתח שלו ברישום. אי"ה אציג את הקוד הנצרך בעת הפנאי.
בינתיים גם אני מצטרף לשאלתו של רחמים.

 

[נדמ]

א. אני מתנצל שהתגובות שלי אינם מיידיות. וזה מפני שלא זכיתי עדיין להיות משתמש "מאושר" והתגובות שלי עוברות ביקורת.
ב. לגופה של שאלה, מדובר בהתקן שמתחבר לארון חשמל ומתפקד כ-16 שעוני שבת מצד אחד ומחובר מצד למחשב ב-USB מצד שני, אך ההתקן הזה מאבד קשר לעיתים, והדרך שלי כרגע לאפס אותו היא או לנתק ולחבר פיזית או לאתחל את המחשב.

 

[Rרחמים]

א. אני מתנצל שהתגובות שלי אינם מיידיות. וזה מפני שלא זכיתי עדיין להיות משתמש "מאושר" והתגובות שלי עוברות ביקורת.
ב. לגופה של שאלה, מדובר בהתקן שמתחבר לארון חשמל ומתפקד כ-16 שעוני שבת מצד אחד ומחובר מצד למחשב ב-USB מצד שני, אך ההתקן הזה מאבד קשר לעיתים, והדרך שלי כרגע לאפס אותו היא או לנתק ולחבר פיזית או לאתחל את המחשב.

נשמע מעניין...
moishy , באיזה מפתח/ות מדובר ?

 

[mat]

תבדוק את הכלים האלו.

זה עובד דרך ה command line

http://www.uwe-sieber.de/drivetools_e.html

זה נראה לי מה שיכול לעשות את מה שביקשת "RestartSrDev"

 

[moishy]

ובכן הנה השיטה:
יש להעתיק את הקוד הבא למודול חדש:

Option Explicit

Private Declare Function RegDeleteKey Lib "advapi32.dll" Alias "RegDeleteKeyA" (ByVal hKey As Long, ByVal lpSubKey As String) As Long
Private Declare Function RegOpenKeyEx Lib "advapi32.dll" Alias "RegOpenKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal ulOptions As Long, ByVal samDesired As Long, phkResult As Long) As Long
Private Declare Function RegEnumKey Lib "advapi32.dll" Alias "RegEnumKeyA" (ByVal hKey As Long, ByVal dwIndex As Long, ByVal lpName As String, ByVal cbName As Long) As Long
Private Declare Function RegQueryValue Lib "advapi32.dll" Alias "RegQueryValueA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal lpValue As String, lpcbValue As Long) As Long
Private Declare Function RegCloseKey Lib "advapi32.dll" (ByVal hKey As Long) As Long


Private Const ERROR_SUCCESS = 0&

Private Const HKEY_CLASSES_ROOT = &H80000000
Private Const HKEY_CURRENT_CONFIG = &H80000005
Private Const HKEY_CURRENT_USER = &H80000001
Private Const HKEY_LOCAL_MACHINE = &H80000002
Private Const HKEY_USERS = &H80000003

Private Const STANDARD_RIGHTS_ALL = &H1F0000
Private Const KEY_QUERY_VALUE = &H1
Private Const KEY_SET_VALUE = &H2
Private Const KEY_CREATE_SUB_KEY = &H4
Private Const KEY_ENUMERATE_SUB_KEYS = &H8
Private Const KEY_NOTIFY = &H10
Private Const KEY_CREATE_LINK = &H20
Private Const SYNCHRONIZE = &H100000
Private Const KEY_ALL_ACCESS = _
        ((STANDARD_RIGHTS_ALL Or _
          KEY_QUERY_VALUE Or _
          KEY_SET_VALUE Or _
          KEY_CREATE_SUB_KEY Or _
          KEY_ENUMERATE_SUB_KEYS Or _
          KEY_NOTIFY Or KEY_CREATE_LINK) And _
          (Not SYNCHRONIZE))
Private Const ERROR_NO_MORE_ITEMS = 259&

Private m_SelectedSection As Long

Private Const REG_BINARY = 3
Private Const REG_DWORD = 4
Private Const REG_DWORD_BIG_ENDIAN = 5
Private Const REG_DWORD_LITTLE_ENDIAN = 4
Private Const REG_EXPAND_SZ = 2
Private Const REG_FULL_RESOURCE_DESCRIPTOR = 9
Private Const REG_LINK = 6
Private Const REG_MULTI_SZ = 7
Private Const REG_NONE = 0
Private Const REG_RESOURCE_LIST = 8
Private Const REG_RESOURCE_REQUIREMENTS_LIST = 10
Private Const REG_SZ = 1

' Delete all the key's subkeys.
Public Sub DeleteSubkeys(ByVal section As Long, ByVal key_name As String)
    Dim hKey As Long
    Dim subkeys As Collection
    Dim subkey_num As Long
    Dim length As Long
    Dim subkey_name As String

    ' Open the key.
    If RegOpenKeyEx(section, key_name, 0&, KEY_ALL_ACCESS, hKey) <> ERROR_SUCCESS Then
        MsgBox "Error opening key '" & key_name & "'"
        Exit Sub
    End If

    ' Enumerate the subkeys.
    Set subkeys = New Collection
    subkey_num = 0
    Do
        ' Enumerate subkeys until we get an error.
        length = 256
        subkey_name = Space$(length)
        If RegEnumKey(hKey, subkey_num, subkey_name, length) <> ERROR_SUCCESS Then Exit Do
        subkey_num = subkey_num + 1

        subkey_name = Left$(subkey_name, InStr(subkey_name, Chr$(0)) - 1)
        subkeys.Add subkey_name
    Loop

    ' Recursively delete the subkeys and their subkeys.
    For subkey_num = 1 To subkeys.Count
        ' Delete the subkey's subkeys.
        DeleteSubkeys section, key_name & "\" & subkeys(subkey_num)

        ' Delete the subkey.
        RegDeleteKey hKey, subkeys(subkey_num)
    Next subkey_num
    
    ' Close the key.
    RegCloseKey hKey
    
End Sub

' Delete this key.
Public Sub DeleteKey(ByVal section As Long, ByVal key_name As String)
Dim pos As Integer
Dim parent_key_name As String
Dim parent_hKey As Long

    If Right$(key_name, 1) = "\" Then key_name = Left$(key_name, Len(key_name) - 1)

    ' Delete the key's subkeys.
    DeleteSubkeys section, key_name

    ' Get the parent's name.
    pos = InStrRev(key_name, "\")
    If pos = 0 Then
        ' This is a top-level key.
        ' Delete it from the section.
        RegDeleteKey section, key_name
    Else
        ' This is not a top-level key.
        ' Find the parent key.
        parent_key_name = Left$(key_name, pos - 1)
        key_name = Mid$(key_name, pos + 1)

        ' Open the parent key.
        If RegOpenKeyEx(section, _
            parent_key_name, _
            0&, KEY_ALL_ACCESS, parent_hKey) <> ERROR_SUCCESS _
        Then
            MsgBox "Error opening parent key"
        Else
            ' Delete the key from its parent.
            RegDeleteKey parent_hKey, key_name

            ' Close the parent key.
            RegCloseKey parent_hKey
        End If
    End If
End Sub

ברישום יש למצוא את המפתח הרצוי:

HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Enum\USBSTOR

לדוגמא:

HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Enum\USBSTOR\Disk&Ven_SanDisk&Prod_Cruzer_Blade&Rev_1.26

ואז להוסיף לקוד את שתי השורות הבאות:

call DeleteSubkeys(&H80000002,"SYSTEM\CurrentControlSet\Enum\USBSTOR\Disk&Ven_SanDisk&Prod_Cruzer_Blade&Rev_1.26")
call DeleteKey(&H80000002,"SYSTEM\CurrentControlSet\Enum\USBSTOR\Disk&Ven_SanDisk&Prod_Cruzer_Blade&Rev_1.26")

בשלב זה מחקנו את ההתקן מהרישום, עכשיו נותר לנו לבצע סריקה חדשה, לצורך כך יש להוריד את הכלי DEVCON.EXE מאתר מייקרוסופט (http://support.microsoft.com/kb/311272/he)
ולהעתיקו לתיקיית System32.
עכשיו נוסיף את השורה הבאה לביצוע הסריקה מחדש:

Call Shell("DEVCON.exe rescan", vbHide)

זהו זה, סוף סוף סיימנו.

בהצלחה.

 

[דוכי בחול]

באיזה שפה זה כתוב?
vb?

 

[moishy]

VB/VBA

 

[Rרחמים]

moishy,איזו חלופה אתה מציע לפונקציות עם ה '$' כמו:

Left$
Right$

בישביל VB שלא מכיר אותם?

 

[moishy]

הפונקציות האלו הם מיועדות למחרוזות, והם מהירים יותר מאחיהם הכללים (ללא ה$). הם גם עובדים בVB, בעצמי בדקתי בVB6 לVB.NET הקוד המצורף לא מועיל בכלל.