אופיס 365 64-32 ביט לתוכנה באקסס

[FullTime]

יצרתי איזה תוכנה קטנה באקסס גירסת 32 ביט
העברתי את זה למישהו שיש לו 64 וזה לא נפתח לו,

יש איזה אפשרות התאמה או שהוא חייב להתקין 32?
תודה לכולם.

 

[moishy]

לא נפתח לו ?!?!

הקובץ אמור להפתח, מקסימום הקוד לא יעבוד.

 

[FullTime]

לא נפתח לו ?!?!

הקובץ אמור להפתח, מקסימום הקוד לא יעבוד.

כנראה שהוא נתקע בטופס הראשון שנפתח..

 

[moishy]

זה כנראה קשור בהצהרות API שלא מתאימות למערכת של 64 סיביות. בלי לראות את הקוד לא אוכל לעזור ביותר מזה.

 

[שמח לעזור]

ומתכנתי אקסס צריכים לדעת:
כל פונקציית API מחייבת את המתכנת להכין גירסה ל32 ו64 נפרדות.
בשביל זה צריך שתי מערכות הפעלה.
(אחת יכולה להיות וירטואלית כמו שמוישי אמר פעם).

 

[moishy]

שמח, הרשה נא לי לחלוק עליך. אין צורך להכין שתי גירסאות אפשר להסתפק באחד שיתמוך גם ב32 סיביות וגם ב64.
לדוגמא:

Option Explicit

#If VBA7 Then
    Public Declare PtrSafe Function GetOpenFileName Lib "comdlg32.dll" Alias _
           "GetOpenFileNameA" (pOpenfilename As OPENFILENAME) As Long

Public Type OPENFILENAME
    lStructSize As Long
    hwndOwner As LongPtr
    hInstance As LongPtr
    lpstrFilter As String
    lpstrCustomFilter As String
    nMaxCustFilter As Long
    nFilterIndex As Long
    lpstrFile As String
    nMaxFile As Long
    lpstrFileTitle As String
    nMaxFileTitle As Long
    lpstrInitialDir As String
    lpstrTitle As String
    flags As Long
    nFileOffset As Integer
    nFileExtension As Integer
    lpstrDefExt As String
    lCustData As Long
    lpfnHook As LongPtr
    lpTemplateName As String
End Type

#Else

    Public Declare Function GetOpenFileName Lib "comdlg32.dll" Alias _
                                            "GetOpenFileNameA" (pOpenfilename As OPENFILENAME) As Long

Public Type OPENFILENAME
    lStructSize As Long
    hwndOwner As Long
    hInstance As Long
    lpstrFilter As String
    lpstrCustomFilter As String
    nMaxCustFilter As Long
    nFilterIndex As Long
    lpstrFile As String
    nMaxFile As Long
    lpstrFileTitle As String
    nMaxFileTitle As Long
    lpstrInitialDir As String
    lpstrTitle As String
    flags As Long
    nFileOffset As Integer
    nFileExtension As Integer
    lpstrDefExt As String
    lCustData As Long
    lpfnHook As Long
    lpTemplateName As String
End Type
#End If
'/////////////////////////////////
'// End code GetOpenFileName    //
'/////////////////////////////////


Public Function GetMyFile(strTitle As String) As String

    Dim OpenFile As OPENFILENAME
    Dim lReturn As Long

    OpenFile.lpstrFilter = ""
    OpenFile.nFilterIndex = 1
    OpenFile.hwndOwner = 0
    OpenFile.lpstrFile = String(257, 0)
    #If VBA7 Then
        OpenFile.nMaxFile = LenB(OpenFile.lpstrFile) - 1
        OpenFile.lStructSize = LenB(OpenFile)
    #Else
        OpenFile.nMaxFile = Len(OpenFile.lpstrFile) - 1
        OpenFile.lStructSize = Len(OpenFile)
    #End If
    OpenFile.lpstrFileTitle = OpenFile.lpstrFile
    OpenFile.nMaxFileTitle = OpenFile.nMaxFile
    OpenFile.lpstrInitialDir = "C:\"
    OpenFile.lpstrTitle = strTitle
    OpenFile.flags = 0
    lReturn = GetOpenFileName(OpenFile)

    If lReturn = 0 Then
        GetMyFile = ""
    Else
        GetMyFile = Trim(Left(OpenFile.lpstrFile, InStr(1, OpenFile.lpstrFile, vbNullChar) - 1))
    End If

End Function

 

[שמח לעזור]

א. ממש לא מרשה לחלוק עלי
ב. אני אכן לא מכיר את ה#if. כלומר לא השתמשתי בו אף פעם.
ג. זה נשאר בלי סימון אדום בעורך? הוא מרוצה כאילו כלום?

 

[moishy]

אכן מדובר בהתניה למהדר, כך שלמרות שהוא יהיה בצבע אדום התוכנה תפעל כראוי בכל המערכות, כיון שאקסס יהדר רק את הקוד המתאים לו.

 

[FullTime]

אני לא מבין, הקודים ב64 שונים מה32?
פקודה של פתיחת טופס כותבים אחרת?

כי בתוכנה הזאת שעשיתי לא מדובר במשהו מיוחד, זה משהו מאוד קטנצ'יק הVB מכיל רק פקודות של פתיחת וסגירת טפסים...

אהה, ויש גם כמה IFים וזהו זה.

 

[moishy]

אני לא מבין, הקודים ב64 שונים מה32?
פקודה של פתיחת טופס כותבים אחרת?

כי בתוכנה הזאת שעשיתי לא מדובר במשהו מיוחד, זה משהו מאוד קטנצ'יק הVB מכיל רק פקודות של פתיחת וסגירת טפסים...

אהה, ויש גם כמה IFים וזהו זה.

א"כ לא אמור להיות בעיה כנראה שהקובץ פגום, תנסה עם עותק אחר.

 

[HUBHCBH]

אני לא מבין, הקודים ב64 שונים מה32?
פקודה של פתיחת טופס כותבים אחרת?

כי בתוכנה הזאת שעשיתי לא מדובר במשהו מיוחד, זה משהו מאוד קטנצ'יק הVB מכיל רק פקודות של פתיחת וסגירת טפסים...

אהה, ויש גם כמה IFים וזהו זה.

קובץ שסוגרים באקסס (accde) בגרסה אחת של ווינדוס לא יפתח בגרסה השניה, וזה אמור להקפיץ הודעה כמו בתמונה המצורפת, צריך לקחת את הקובץ כשהוא פתוח ולסגור אותו במחשב שבו מותקנת הגרסה השניה.

בהקשר לשמח לעזור, ההתניה עובדת מצוין, כפי שכתב מושי, לא צריך להתייחס לשורה האדומה (אם מפריע השגיאה שקופצת ההודעה, אפשר להוריד אותה)
אם זאת כמובן שלסדר את התוכנה ל64 ביט זה מצריך קצת סבלנות לשינוי הקוד כמו בהצהרת נתונים (לדוגמה Long יהפוך ל LongLong)

בהצלחה

 

[moishy]

אכן צריך סבלנות, אבל לא כל Long נהפך לLongLong.

 

[שמח לעזור]

אכן מדובר בהתניה למהדר, כך שלמרות שהוא יהיה בצבע אדום התוכנה תפעל כראוי בכל המערכות, כיון שאקסס יהדר רק את הקוד המתאים לו.

אז כל עוד הקוד הזה נמצא א"א לדבג את הקוד, לא כן?
או שבגלל שרק ההצהרה "שגוייה", הוא "מסכים" לדבג פונקציות שקוראות לו?
אם כן, צדקתי בצורך שתי המערכות (או יותר נכון לא לפתח לאסס )

 

[moishy]

אין שום בעיה להדר (לקמפל את הקוד) וכן לנפות שגיאות (לדבג), אתה מוזמן לבדוק זאת בעצמך על הקוד שהעליתי או לכתוב קוד חדש בעצמך!

ובהחלט לא צדקת, אין שום צורך בשתי מערכות, ואני חושב שהקוד שהעליתי מדגים זאת היטב.

אמנם ה"מקצוענים" מזלזלים בפיתוח תוכנות באקסס, אבל... יש באקסס הרבה תכונות טובות מועילות הן מקלות על תהליך פיתוח התוכנה והן על ההגנה עליה, שאין כדוגמתו בשום פלטפורמה אחרת! אמנם לעיתים נדרשת יצירתיות להגבר על בעיות מסוימות, אבל טרם נתקלתי בבעיה שלא נמצאה לה פתרון.

 

[שמח לעזור]

אין שום בעיה להדר (לקמפל את הקוד) וכן לנפות שגיאות (לדבג), אתה מוזמן לבדוק זאת בעצמך על הקוד שהעליתי או לכתוב קוד חדש בעצמך!

מוותר על התענוג.

ובהחלט לא צדקת, אין שום צורך בשתי מערכות, ואני חושב שהקוד שהעליתי מדגים זאת היטב.

עכ"פ לסגירה לקובץ הפעלה צריך שתיים, לא כן?

אמנם ה"מקצוענים" מזלזלים בפיתוח תוכנות באקסס, אבל... יש באקסס הרבה תכונות טובות מועילות הן מקלות על תהליך פיתוח התוכנה והן על ההגנה עליה, שאין כדוגמתו בשום פלטפורמה אחרת! אמנם לעיתים נדרשת יצירתיות להגבר על בעיות מסוימות, אבל טרם נתקלתי בבעיה שלא נמצאה לה פתרון.

אני לא כ"כ מקצוען. רק אעיר, שטרם נמצאה דרך כל שהיא שעבירה ברכב מנועי ולא במרכבת סוסים ויש הרבה הרבה מעלות לזו האחרונה מהרבה בחינות . בהצלחה לכולם בכל אופן.

 

[HUBHCBH]

מוותר על התענוג.

עכ"פ לסגירה לקובץ הפעלה צריך שתיים, לא כן?

אכן כן, לסגירה צריך 2, לא מסובך, אלא פשוט לשמור בשם באופיס שיש בו 64 ביט וכן לשמור בשם באופיס 32 ביט, או להשאיר פתוח.

הערה חשובה: גם במחשב של 64 ביט אפשר להתקין אופיס 32 ביט וכך לפתור את הבעיה!

 

[שמח לעזור]

אכן כן, לסגירה צריך 2, לא מסובך, אלא פשוט לשמור בשם באופיס שיש בו 64 ביט וכן לשמור בשם באופיס 32 ביט, או להשאיר פתוח.

הערה חשובה: גם במחשב של 64 ביט אפשר להתקין אופיס 32 ביט וכך לפתור את הבעיה!

מה לא מסובך פה
אפשר במחשב להתקין או 32 או 64. לא מסובך מספיק?

 

[HUBHCBH]

מה לא מסובך פה
אפשר במחשב להתקין או 32 או 64. לא מסובך מספיק?

כוונתי היתה שגם על מחשב שמערכת ההפעלה שלו היא ווידנוס 64 ביט אפשר להתקין אופיס 32 ביט.